미분하는 프로그램 2 - 출력을 개선하기

; symbolic data가 들어오면 미분합니다. 지금은 더하기와 곱하기 밖에 지원하지 않습니다.
; 참고로 미분 공식은 d(u + v)/dx = d(u)/dx + d(v)/dx, d(u * v)/dx = u*(dv/dx) + v*(du/dx) 입니다.
; d(-u)/dx = - d(u)/dx
; d(u - v)/dx = d(u)/dx - d(v)/dx
; d(u^n)/dx = n*n^(n-1)(du/dx) 를 처리할 수 있도록 코드가 추가됩니다.
(define (deriv exp var)
  (cond ((number? exp) 0)
        ((variable? exp)
         (if (same-variable? exp var) 1 0))
        ((negative? exp) (make-negative (deriv (negand exp) var)))
        ((sum? exp)
         (make-sum (deriv (addend exp) var)
                   (deriv (augend exp) var)))
        ((difference? exp)
         (make-difference (deriv (minuend exp) var)
                          (deriv (subtrahend exp) var)))
        ((product? exp)
         (make-sum
          (make-product (multiplier exp)
                        (deriv (multiplicand exp) var))
          (make-product (deriv (multiplier exp) var)
                        (multiplicand exp))))
        ((exponentiation? exp)
         (make-product
          (make-product (exponent exp) 
                        (make-exponentiation (base exp)
                                             (make-difference (exponent exp) 1)))
          (deriv (base exp) var)))
        (else
         (error "unknown expression type -- DERIV" exp))))
 
(define (variable? x) (symbol? x))
 
(define (same-variable? v1 v2)
  (and (variable? v1) (variable? v2) (eq? v1 v2)))
 
; 추가됩니다.
(define (=number? exp num)
  (and (number? exp) (= exp num)))
 
;(define (make-sum a1 a2) (list '+ a1 a2)) 더 계산을 해서 결과가 보기 좋도록 수정됩니다.
(define (make-sum a1 a2)
  (cond ((=number? a1 0) a2)
        ((=number? a2 0) a1)
        ((and (number? a1) (number? a2)) (+ a1 a2))
        (else (list '+ a1 a2))))
 
;(define (make-product m1 m2) (list '* m1 m2)) 더 계산을 해서 결과가 보기 좋도록 수정됩니다.
(define (make-product m1 m2)
  (cond ((or (=number? m1 0) (=number? m2 0)) 0)
        ((=number? m1 1) m2)
        ((=number? m2 1) m1)
        ((and (number? m1) (number? m2)) (* m1 m2))
        (else (list '* m1 m2))))
 
(define (sum? x)
  (and (pair? x) (eq? (car x) '+)))
 
(define (addend s) (cadr s))
 
(define (augend s) (caddr s))
 
(define (product? x)
  (and (pair? x) (eq? (car x) '*)))
 
(define (multiplier p) (cadr p))
 
(define (multiplicand p) (caddr p))
 
; 여기서부터 음수의 미분에 필요한 코드
(define (make-negative n)
  (cond ((number? n) (- n))
        (else (list '- n))))
 
(define (negative? x)
  (and (pair? x) (eq? (car x) '-) (= (length x) 2)))
 
(define (negand n) (cadr n))
 
; 여기서부터 빼기의 미분에 필요한 코드
(define (make-difference a1 a2)
  (cond ((=number? a1 0) (make-negative a2))
        ((=number? a2 0) a1)
        ((and (number? a1) (number? a2)) (- a1 a2))
        (else (list '- a1 a2))))
 
(define (difference? x)
  (and (pair? x) (eq? (car x) '-) (= (length x) 3)))
 
(define (minuend d) (cadr d))
 
(define (subtrahend d) (caddr d))
 
; 여기서부터 거듭제곱의 미분에 필요한 코드
(define (make-exponentiation e1 e2)
  (cond ((or (=number? e1 0) (=number? e1 1)) e1)
        ((=number? e2 0) 1)
        ((=number? e2 1) e1)
        ((and (number? e1) (number? e2)) (** e1 e2))
        (else (list '** e1 e2))))
 
(define (exponentiation? x)
  (and (pair? x) (eq? (car x) '**)))
 
(define (base e) (cadr e))
 
(define (exponent e) (caddr e))
 
;; 예전 문제와 답
;
;(deriv '(+ x 3) 'x)
;;답 (+ 1 0)
;
;(deriv '(* x y) 'x)
;;답 (+ (* x 0) (* 1 y))
;
;(deriv '(* (* x y) (+ x 3)) 'x)
;;답 (+ (* (* x y) (+ 1 0)) (* (+ (* x 0) (* 1 y)) (+  x 3)))
 
; 여기서 부터 새로 바뀐 출력
(deriv '(+ x 3) 'x)
;1
 
(deriv '(* x y) 'x)
;y
 
(deriv '(* (* x y) (+ x 3)) 'x)
;(+ (* x y) (* y (+ x 3)))
 
; 음수, 빼기, 거듭제곱 문제
(deriv '(- x) 'x)
;-1
 
(deriv '(- (* x 3) 4) 'x)
;3
 
(deriv '(- (** x 2)) 'x)
;(- (* 2 x))