emacs shell모드에서 파일을 여는방법

일단 eshell이라는 순수 elisp으로 만들어진 shell이 있습니다. 최근 버젼에는 디폴트로 들어가 있습니다. zsh과 같은 강력한 glob기능이 우선 돋보이고, 대부분의 기본 명령어를 emacs lisp으로 직접 만들었기 때문에 windows같은 이 기종에서도 사용이 가능합니다.

여튼 shell모드에 대해서 한정해서 답을 드리겠습니다.
1. 파일 편집
Kai가 전에 얘기한 방식이 있습니다.

(add-hook 'shell-mode-hook  'shell-integration-hook)
(defun shell-integration-hook ()
  (make-local-variable 'comint-input-sender)
  (setq comint-input-sender 'shell-integration-sender))

(defun shell-integration-sender (process command)
  (setq command command)
  (let* ((program (comint-arguments command 0 0))
	 (func (intern (format "shell/%s" program))))
    (if (not (fboundp func))
	(comint-simple-send process command)
      (comint-simple-send process (format "# %s" command))
      (funcall func process command))))

와 같이 하시고,

(defun shell/vi (process command)
  (find-file (comint-arguments command 1 1) nil))

(defun shell/make (process command)
  (compile command))

등과 같이 하시면, shell에서 "vi filename" 하시면 filename이 emacs에서 열리고, make를 치면 알아서 compile버퍼로 넘어가서 실행이 됩니다.

2. 그에 해당하는 명령이 M-p, M-n입니다.

   (add-hook 'shell-mode-hook  'shell-custom-bindings) 
   (defun shell-custom-bindings ()
     (define-key shell-mode-map (kbd "<up>") (kbd "M-p"))
     (define-key shell-mode-map (kbd "<down>") (kbd "M-n"))
     (define-key shell-mode-map (kbd "C-p") (kbd "M-p"))
     (define-key shell-mode-map (kbd "C-n") (kbd "M-n")))