문자열에서 수학기호를 논리 연산식 처럼 바꾸는 게 잘 안 되네요...

제일 안쪽 괄호 안의 내용을 따로 저장하고 그 자리를 하나의 항으로 치환하는 과정을 반복하고
 
   ( AAA + BBB ) + [ { ( CCC + DDD + EEE ) - FFF } & GGG ]
=>     TERM1     + [ {        TERM2        - FFF } & GGG ]
=>     TERM1     + [               TERM3           & GGG ]
=>     TERM1     +                   TERM4
=> TERM5
 
그 다음은 역으로 하나의 항을 원하는 형태의 괄호식으로 바꾸면서 치환
 
   TERM5
=> ( TERM1 OR TERM4 )
=> ...

use strict;
use warnings;
 
my $str = '( AAA + BBB ) + [ { ( CCC + DDD + EEE ) - FFF } & GGG ]';
 
# 각 부분식을 저장할 해시와, 부분식의 인덱스
my $idx = 0;
my %save;
 
 
# 전체 식을 괄호로 한 번 감싸서 하나의 항으로 만듦
$str = "( $str )";
 
# 가장 안쪽 괄호부터 차례대로 저장
while ( 
    $str =~ s/
                ( [(\[\{] )     # 시작 괄호
                \s*             # 공백이 있을 수도
                ( [^(\[\{]+? )  # 괄호 안의 내용
                \s*
                ( [)\]\}] )     # 끝 괄호
            /
                save($1,$2,$3)  # 이 식을 변환,저장한 후 'TERM숫자' 형태로 치환
            /gex
) {}
 
# 'TERM숫자' 형태로 저장된 내용을 변환된 식으로 복원
while ( $str =~ s/(TERM\d+)/$save{$1}/g ) {}
 
# 제일 바깥쪽에 추가했던 괄호 제거
$str =~ s/^\( //;
$str =~ s/ \)$//;
 
print $str, "\n";
 
exit;
 
 
# 괄호로 둘러싸인 부분식을 저장하는 함수
sub save {
    my ($open, $expr, $close) = @_;
 
    my %opword = (
        '-' => 'NOT',
        '+' => 'OR',
        '&' => 'AND',
    );
    my $converted;
 
    # -,+,& 중에 하나가 들어있는지 추출
    my ($op) = $expr =~ /([-+&])/;
 
    if ( $op ) {
        # 부분식 안에 연산자가 들어있다면 그 연산자를 구분자로 해서
        # 부분식을 여러 항들로 쪼갠다
        my @terms = split /\s*\Q$op\E\s*/, $expr;
 
        if ( @terms == 2 ) {
            # 항이 두 개면 연산자를 가운데
            $converted = "$terms[0] $opword{$op} $terms[1]";
        }
        else {
            # 항이 세 개 이상이거나,
            # 그럴리는 없겠지만 항이 1개거나 없는 경우
            # 연산자를 앞에
            $converted = "$opword{$op} @terms";
        }
    }
    else {
        # 연산자가 들어 있지 않은 단항인 경우
        $converted = $expr;
    }
 
    my $key = "TERM" . ++$idx;
    $save{$key} = "$open $converted $close";
    return $key;
}