[완료]리스트내에 가변노드 알고리즘에 대해..조언좀

#!/usr/bin/env perl
use strict;
use warnings;
 
# 정규식 패턴
# (\w+) 부분이 위치에 매치
my $pat_list = qr/LIST\d+/;
my $pat_node = qr/NODE\d+_(\w+)/;
my $pat_object = qr/object_(\w+)/;
 
my ( $list_name, @node_list, %node_to_loc, %loc_to_object) = ( '' );
while ( my $line = <> ) {
    chomp $line;
 
    if ( $line =~ /^($pat_list) - ($pat_node)/ ) {
        print_current_list();       # 새 리스트가 시작될 때마다 그 전까지 읽은 부분을 출력
        $list_name = $1;
        @node_list = ( $2 );
        %node_to_loc = ( $2 => $3 );
        %loc_to_object = ();
    }
    elsif ( $line =~ /^\s+($pat_node)/ ) {
        push @node_list, $1;
        $node_to_loc{$1} = $2;
    }
    elsif ( $line =~ /^\s+($pat_object)/ ) {
        $loc_to_object{$2} = $1;
    }
}
print_current_list();
 
sub print_current_list {
    return if $list_name eq '';
 
    print $list_name, "\n";
    foreach my $node ( @node_list ) {
        print $node;
 
        if ( exists $loc_to_object{ $node_to_loc{$node} } ) {
            print " ", $loc_to_object{ $node_to_loc{$node} };
        }
 
        print "\n";
    }
}

$ ./conv.pl input.txt
LIST1
NODE1_xy1 object_xy1
NODE2_xy2
NODE3_xy3
LIST2
NODE1_xy1 object_xy1
NODE2_xy2
LIST3
NODE1_xy1 object_xy1
NODE2_xy2 object_xy2
NODE3_xy3
NODE4_xy4
NODE5_xy5 object_xy5