[완료]perl 질문있습니다~ ( _ _ )

1. C의 #define 으로 상수 정의하는 기법을 perl에서는 어떻게 구현하는지요?

일단 여러가지 방법이 있습니다만, 간단하게 자주 사용하는
세가지 정도를 말씀드립니다. 개인적으로는 3번 추천드립니다. :-)

1. 변수명을 대문자로 사용한다. 그리고 대문자 변수명에는 값을 할당하지 않는다.

    my $PI = 3.14;
    my $IP = '192.168.0.1';
...

2. use constant를 이용한다. 터미널에서 perldoc constant 를 실행해서
문서를 참조. 또는 여기를 참조

    use constant PI    => 4 * atan2(1, 1);
    use constant DEBUG => 0;
 
    print "Pi equals ", PI, "...\n" if DEBUG;
 
    use constant {
        SEC   => 0,
        MIN   => 1,
        HOUR  => 2,
        MDAY  => 3,
        MON   => 4,
        YEAR  => 5,
        WDAY  => 6,
        YDAY  => 7,
        ISDST => 8,
    };
 
    use constant WEEKDAYS => qw(
        Sunday Monday Tuesday Wednesday Thursday Friday Saturday
    );
 
    print "Today is ", (WEEKDAYS)[ (localtime)[WDAY] ], ".\n";

3. CPAN Readonly 모듈 사용(설치요망). 여기를 참조

    use Readonly;
 
    Readonly my $sca => $initial_value;
    Readonly my @arr => @values;
    Readonly my %has => (key => value, key => value, ...);

2. use strict;를 넣었을 때 'Global symbol "$fileindex" requires explicit package name' 라는 에러 메시지를 어떻게 해결하는지 알고싶습니다.

이 문제는 패키지변수(전역변수)와 지역변수(렉시컬변수)와 관련한 문제입니다.
use strict 프라그마를 사용하면 반드시 패키지 변수를 사용할때는
정확하게 패키지(prefix)를 명시해야 합니다.

즉 현재 $fileindex를 선언한적이 없는데(렉시컬로) 너는 지금 사용하고 있다.
그렇다면 너는 $fileindex가 전역 변수란 말인가? 그렇다면 패키지 명을
명시하라! 라고 경고를 하는 것입니다.

만약 정말로 전역 변수라면 $main::fileindex 또는 $MyModule::fileindex와
같이 정확하게 패키지 명(여기서는 main, MyModule)을 명시해줘야 하고
사실 대부분의 경우처럼 전역변수가 아니라 지역변수로 사용하기를 원한다면
최초 $fileindex를 처음으로 사용하는 시점에 지역변수(렉시컬)로 한정해줘야 합니다.

즉,

my $fileindex;
my $dirindex = '.';
my @files = ();
my %people = (
    name => 'Keedi Kim',
    nick => 'keedi',
);

라고 해줘야 하는 거죠~ :-)

---------------------------
Smashing Watermelons~!!
Whatever Nevermind~!!

Keedi Kim