특정문자를 구분자로 해서 파일을 나누는 방법이 있나여?

#!/usr/bin/perl 
 
use strict;
use warnings;
 
die usage() unless @ARGV >= 1;
my $delim = shift;
 
my %subfile = (
    number  => 0,
    prefix  => 'delim-',
    postfix => '.txt',
    lines   => [],
);
 
LOOP_LINES:
while ( my $line = <> ) {
 
    if ( $line !~ m/^$delim$/ ) {
        push @{$subfile{lines}}, $line;
        next LOOP_LINES;
    }
 
    save_to_file(
        "$subfile{prefix}$subfile{number}$subfile{postfix}",
        @{$subfile{lines}}
    );
 
    $subfile{lines} = [];
    ++$subfile{number};
}
 
if ( @{$subfile{lines}} ) {
    save_to_file(
        "$subfile{prefix}$subfile{number}$subfile{postfix}",
        @{$subfile{lines}}
    );
}
 
sub save_to_file {
    my $file  = shift;
    my @lines = @_;
 
    open my $fh, '>', $file
        or die "cannot open $file : $!\n";
    print $fh @lines;
    close $fh;
}
 
sub usage {
    my $str = <<"END_USAGE";
 
USAGE
=====
 
  $0 <delimeter> <file> [<file> ...]
 
END_USAGE
 
    return $str;
}