DC 인사이드의 여친겔 긁어오기...

GUI를 입혀봤습니다..

이미지를 직접 다운로드에 조금은 문제가 있지만...

그래도 쓸만 하실겁니다...

아래의 페이지에서 다운로드 받으세요..

참고로 이번 GUI는 윈도우즈 XP 이상에서만 실행됩니다..

그리고 이미지를 다운로드시에는 현재 실행된 위치로 복사됩니다.

귀차니즘때문에 다운로드 경로 지정하는것을 넣지 않았습니다.

시간에 되면 다음 버전에 기능을 추가후 다시 릴리즈 하겠습니다.

http://sukihaki.net/dbwiki/index.php/DC%20Inside%20Gallery%20Downloader

다음버전엔 갤러리를 동적으로 추가할수 있도록 하겠습니다.

완전한 소스를 올립니다.

소스를 받아서 보셔도 되겠지만...

혹시 소스를 보시고..

개선할점이나 직접 개선해 주실분은 참고 바랍니다.

set libdir [file join $starkit::topdir lib]

lappend auto_path $libdir
#lappend auto_path .

package require tile
package require http

namespace import -force tile::*

tile::setTheme winnative

wm title . "DC Inside Gallery Downloader 1.1"

proc insertText { str } {
	variable text

	$text insert end $str
	$text see end
}

proc writeHtml { url } {
	variable gallery
	variable downloadto

	set file [file normalize "$downloadto/$gallery\.html"]
	set h [open $file a]
	puts $h "<img src=$url><br>"
	close $h
}
	
proc pageParse { pageUrl } {
	variable baseUrl
	variable is_stop

	set token [::http::geturl $pageUrl]
	set html [::http::data $token]
	set pattern {<a href="zboard?([/]*)"?[^>]*>}

	foreach url [regexp -all -nocase -inline $pattern $html] {
		if { $is_stop == 1 } break

		if { [string length $url] > 0 } {
			set url $baseUrl[lindex [split $url \"] 1]
			postParse $url
		}
	}
}

proc postParse { url } {
	variable baseUrl
	
	variable gallery

	variable is_html
	variable is_down

	variable is_stop

	set token [::http::geturl $url]
	set html [::http::data $token]

	switch $gallery {
		"girl" { set pattern {<img src=http://kr.img.dc.yahoo.com/b1/data/girl"?([/]*)"?[^>]*>} }
		"taehee" { set pattern {<img src=http://kr.img.dc.yahoo.com/b5/data/taehee"?([/]*)"?[^>]*>} }
		"racinggirl" { set pattern {<img src=http://kr.img.dc.yahoo.com/b3/data/racinggirl"?([/]*)"?[^>]*>} }
		"moon" { set pattern {<img src=http://kr.img.dc.yahoo.com/b5/data/moon"?([/]*)"?[^>]*>} }
		"hancy" { set pattern {<img src=http://kr.img.dc.yahoo.com/b1/data/hancy"?([/]*)"?[^>]*>} }
	}

	foreach url [regexp -all -nocase -inline $pattern $html] {
		if { $is_stop == 1 } break

		if { [string length $url] > 1 } {
			set url [lindex [split [lindex [split $url] 1] =] 1]
			set url [encoding convertfrom cp949 $url]
			
			if { $is_html == 1 } {		
				writeHtml $url
			}
         
			if { $is_down == 1 } {
				after 0 [list getUrl $url]
			}
		}
	}
}

proc getUrl {url} {
	variable progresssourcelabel
	variable progressdownloadtolabel
	variable downloadto
	variable data

	regexp {http://.*/([^/]+)$} $url -> file
	
	set validate [::http::geturl $url -validate 1]
		
	set file [file normalize "$downloadto/$file"]
	$progresssourcelabel configure -text "Image From : $url"
	$progressdownloadtolabel configure -text "Download To : $file"

	set fid [open $file w]
	fconfigure $fid -translation binary -encoding binary

	set token [::http::geturl $url \
		-timeout 10000 \
		-channel $fid \
		-progress [list [namespace code progress]] \
		-command [list [namespace code cleanup] $url $fid]]
	
	set data($token,fid) $fid
	set data($token,url) $url

}

proc progress {token expected received} {
	variable progress
	variable ctoken

	set ctoken $token

	if {$expected == 0} { return }
	set percent [expr {int(100.0 * (double($received)/double($expected)))}]

	$progress configure -value $percent
}

proc cleanup {url fid token} {
	variable data

	if {[http::status $token] != "Cancelled"} {
		if {[http::ncode $token] == 301 || [http::ncode $token] == 302} {
			http::cleanup $token
			after 0 [list getUrl $data($token,url)]
			return
		} elseif {[string match 2?? [http::ncode $token]]} {
			insertText "$data($token,url) .. Done. ([expr [http::size $token] / 1024] Kbytes.)\n"
			http::cleanup $token
			close $data($token,fid)

		} else {
			insertText "ERROR: [http::ncode $token] [http::status $token])\n"
		}
	}
}

proc stop { } {
	variable ctoken
	variable is_stop

	if [info exist ctoken] {
		http::reset $ctoken "Cancelled"
	}

	set is_stop 1
}

proc start { } {
	variable baseUrl
	variable board
	variable boardName
	variable pageUrl

	variable startbutton
	variable stopbutton 
	variable exitbutton
	variable galleryradio

	variable downloadcheckbutton
	variable htmlcheckbutton

	variable downloadtoentry
	variable downloadtobutton

	variable gallery
	variable is_down
	variable is_html
	variable is_stop
	
	variable frompage
	variable topage
	variable downloadto
	
	variable frompagespinbox
	variable topagespinbox

	set is_stop 0

	$frompagespinbox configure -state disabled
	$topagespinbox configure -state disabled
	$startbutton configure -state disabled
	$stopbutton configure -state normal
	$exitbutton configure -state disabled
	$galleryradio(girl) state disabled
	$galleryradio(taehee) state disabled
	$galleryradio(racinggirl) state disabled
	$galleryradio(moon) state disabled
	$galleryradio(hancy) state disabled
	$downloadcheckbutton state disabled
	$htmlcheckbutton state disabled
	$downloadtoentry configure -state disabled
	$downloadtobutton configure -state disabled

	set file [file normalize "$downloadto/$gallery\.html"]
	file delete $file

	set board "zboard.php?id="
	set pageUrl "&page="
	set boardName $gallery

	switch $gallery {
		"girl" { set baseUrl "http://kr.dcinside1.imagesearch.yahoo.com/zb40/" }
		"taehee" { set baseUrl "http://kr.dcinside5.imagesearch.yahoo.com/zb40/" }
		"racinggirl" { set baseUrl "http://kr.dcinside3.imagesearch.yahoo.com/zb40/" }
		"moon" { set baseUrl "http://kr.dcinside5.imagesearch.yahoo.com/zb40/" }
		"hancy" { set baseUrl "http://kr.dcinside1.imagesearch.yahoo.com/zb40/" }
	}
	
	for { set pageNo $frompage } { $pageNo <= $topage } { incr pageNo } {
		if { $is_stop == 1 } break

		insertText "$pageNo 페이지 분석 중 ...\n"

		pageParse "$baseUrl$board$boardName$pageUrl$pageNo"

		if { $is_stop == 1 } {
			insertText "정지 !!\n"
		} {
			insertText "완료 !!\n"
		}
	}

	$startbutton configure -state normal
	$stopbutton configure -state disabled
	$exitbutton configure -state normal
	$galleryradio(girl) state !disabled
	$galleryradio(taehee) state !disabled
	$galleryradio(racinggirl) state !disabled
	$galleryradio(moon) state !disabled
	$galleryradio(hancy) state !disabled
	$downloadcheckbutton state !disabled
	$htmlcheckbutton state !disabled
	$frompagespinbox configure -state normal
	$topagespinbox configure -state normal
	$downloadtoentry configure -state !disabled
	$downloadtobutton configure -state !disabled
}

proc about { } {
	tk_messageBox -title "About" \
		-message \
		" DC Inside Gallery Downloader 1.1\n\n\
		Written in Tcl/Tk\n\n\
		제작자 : 민인학 (haki@sukihaki.net)\n\n\
		Tcl/Tk Korea Community (http://tcltk.co.kr)  "
}

proc validateNumber { } {
	variable frompage
	variable topage

	variable frompagespinbox
	variable topagespinbox

	if { $frompage > $topage } {
		$topagespinbox set $frompage
	}
}

proc nokey { } {
	bell
	return 0
}

proc usekey { } {
	return 1
}

proc DcGallery { } {
	variable startbutton
	variable stopbutton 
	variable exitbutton

	variable galleryradio
	variable downloadcheckbutton
	variable htmlcheckbutton
	
	variable downloadtoentry
	variable downloadtobutton

	variable text

	variable gallery
	variable is_down
	variable is_html

	variable progress
	variable progresssourcelabel
	variable progressdownloadtolabel

	variable frompage
	variable topage

	variable frompagespinbox
	variable topagespinbox

	set top [frame .top]

	set topleftframe [frame $top.topleftframe]
	
	# 페이지
	set pageframe [labelframe $topleftframe.pageframe -text "Page"]
	set frompagelabel [label $pageframe.frompagelabel -text "From : "]
	pack $frompagelabel -side left
	set frompagespinbox [spinbox $pageframe.frompagespinbox \
		-textvariable frompage \
		-state readonly \
		-from 1 -to 9999 -increment 1 -width 4 \
		-command validateNumber
	]
	pack $frompagespinbox -side left
	set topagelabel [label $pageframe.topagelabel -text "  To : "]
	pack $topagelabel -side left
	set topagespinbox [spinbox $pageframe.topagespinbox \
		-textvariable topage \
		-state readonly \
		-from 1 -to 9999 -increment 1 -width 4 \
		-command validateNumber
	]
	pack $topagespinbox -side left
	pack $pageframe -side top -fill x

	# 갤러리 선택
	set galleryframe [labelframe $topleftframe.galleryframe -text "Gallery"]
	set galleryradio(girl) [radiobutton $galleryframe.galleryradio(girl) \
		-text "여친/애인 갤러리" -variable gallery -value girl]
	pack $galleryradio(girl) -side top -anchor nw
	set galleryradio(taehee) [radiobutton $galleryframe.galleryradio(taehee) \
		-text "김태희 갤러리" -variable gallery -value taehee]
	pack $galleryradio(taehee) -side top -anchor nw
	set galleryradio(racinggirl) [radiobutton $galleryframe.galleryradio(racinggirl) \
		-text "레이싱걸 갤러리" -variable gallery -value racinggirl]
	pack $galleryradio(racinggirl) -side top -anchor nw
	set galleryradio(moon) [radiobutton $galleryframe.galleryradio(moon) \
		-text "문근영 갤러리" -variable gallery -value moon]
	pack $galleryradio(moon) -side top -anchor nw
	set galleryradio(hancy) [radiobutton $galleryframe.galleryradio(hancy) \
		-text "한채영 갤러리" -variable gallery -value hancy]
	pack $galleryradio(hancy) -side top -anchor nw
	pack $galleryframe -side top -fill y -fill x -anchor nw -expand true
	
	$galleryradio(girl) invoke
	
	pack $topleftframe -anchor nw -side left -fill y -padx 3


	# 로그 영역
	set topright [labelframe $top.topright -text "Log"]
	set text [text $topright.text -height 20 -font {굴림체 9}]
	pack $text -fill both -expand true -padx 3 -pady 3
	pack $topright -side left -fill both -expand true -padx 3

	pack $top -side top -fill both -expand true

	# 진행상황
	set center [labelframe .center]

	set htmlframe [frame $center.htmlframe]
	set htmlcheckbutton [checkbutton $htmlframe.htmlcheckbutton \
		-text "Write HTML" -variable is_html]
	pack $htmlcheckbutton -side left
	pack $htmlframe -side top -fill x
	
	set downloadframe [frame $center.downloadframe]
	set downloadcheckbutton [checkbutton $downloadframe.downloadcheckbutton \
		-text "Download Image" -variable is_down]
	pack $downloadcheckbutton -side left
	
	set downloadtoframe [frame $downloadframe.downloadtoframe -width 10]
	set downloadtoentry [entry $downloadframe.downloadtoentry -width 70 \
		-textvariable downloadto]
	set downloadtobutton [button $downloadframe.downloadtobutton -text "..." -width 3 -command {
			set dir [tk_chooseDirectory]
			if { $dir != "" } {
				$downloadtoentry configure -validatecommand  { usekey }
				$downloadtoentry delete 0 end
				$downloadtoentry insert 0 $dir
				$downloadtoentry configure -validate key -validatecommand  { nokey }
			}
		}
	]
	pack $downloadtoframe $downloadtoentry $downloadtobutton -side left
	pack $downloadframe -side top -fill x

	$downloadtoentry insert 0 [pwd]
	$downloadtoentry configure -validate key -validatecommand  { nokey }
	
	$htmlcheckbutton invoke
	set is_down 0

	set progressframe [labelframe $center.progressframe]
	set progresssourcelabel [label $progressframe.progresssourcelabel -text "Image From :"]
	pack $progresssourcelabel -side top -anchor nw -padx 3
	set progressdownloadtolabel [label $progressframe.progressdownloadtolabel -text "Download To :"]
	pack $progressdownloadtolabel -side top -anchor nw -padx 3
	set progress [ttk::progressbar $progressframe.progress \
		-orient horizontal -maximum 100]
	pack $progress -side top -fill x -pady 3 -padx 3
	pack $progressframe -side top -fill x

	pack $center -side top -fill x -padx 3

	# 버튼
	set bottom [frame .bottom]
	set exitbutton [button $bottom.exitbutton -text "Exit" \
		-command { exit } ]
	pack $exitbutton -side right -padx 5
	set stopbutton [button $bottom.stopbutton -text "Stop" \
		-command { stop } ]
	pack $stopbutton -side right
	set startbutton [button $bottom.startbutton -text "Start" \
		-command { start } ]
	pack $startbutton -side right
	set aboutbutton [button $bottom.aboutbutton -text "About" \
		-command { about } ]
	pack $aboutbutton -side left -anchor nw
	pack $bottom -side top -fill x -pady 3 -padx 3

	$stopbutton configure -state disabled
}

DcGallery